User:Metamorforme42/Ambassadors

From Wikidata
Jump to navigation Jump to search
Ontology for ambassadors
Ontology related to ambassadors
type of case item subclass of (P279) instance of (P31) comment
for classification metaclass of ambassadors (Q29918297) second-order class (Q24017414) of (P642) ambassador (Q121998) third-order class (Q24017465) is a metametaclass
class of ambassadors (Q29918287) class (Q16889133) of (P642) ambassador (Q121998) metaclass of ambassadors (Q29918297) is a metaclass
class of ambassadors of a country (Q29918328) class of ambassadors (Q29918287) metaclass of ambassadors (Q29918297) metasubclass of (P2445) class of ambassadors (Q29918287) (see column subclass of (P279) of generalization of a particular case)
class of ambassadors of a no longer existing country (Q30082664) class of ambassadors of a country (Q29918328) metaclass of ambassadors (Q29918297) when the country no longer exists
class of ambassadors to a country (Q29918335) class of ambassadors (Q29918287) metaclass of ambassadors (Q29918297) metasubclass of (P2445) class of ambassadors (Q29918287) (see column subclass of (P279) of generalization of a particular case)
class of ambassadors to a no longer existing country (Q30064737) class of ambassadors to a country (Q29918335) metaclass of ambassadors (Q29918297) when the country no longer exists
general case head of mission (Q1251687) position (Q4164871) P279 and P31 not complete on this line
ambassador (Q121998) head of mission (Q1251687) diplomatic rank (Q303618) P279 and P31 not complete on this line
ambassador of a country (Q29645880) ambassador (Q121998) class of ambassadors of a country (Q29918328) is a class => not a position,

but a subclass of position

ambassador of former countries and unions (Q110620461) ambassador of a country (Q29645880) class of ambassadors of a country (Q29918328) when the country no longer exists
ambassador to a country (Q29645886) ambassador (Q121998) class of ambassadors to a country (Q29918335) is a class => not a position,

but a subclass of position

ambassador to a no longer existing country (Q30064715) ambassador to a country (Q29645886) class of ambassadors to a country (Q29918335) when the country no longer exists
particular case ambassador of France (Q28061729) ambassador of a country (Q29645880) class of ambassadors of a country (Q29918328) should not be used with position held (P39) (if used with => data should be completed)
ambassador to Germany (Q28796675) ambassador to a country (Q29645886) class of ambassadors to a country (Q29918335) should not be used with position held (P39) (if used with => data should be completed)
ambassador of France to Germany (Q20942020) NONE : nothing should be an ambassador of France to Germany (only used with position held (P39)) ambassador to Germany (Q28796675) and ambassador of France (Q28061729) is a position (from subclass relation of it’s instances)
generalization of a particular case ambassador of X ambassador of a country (Q29645880) class of ambassadors of a country (Q29918328) with X = a country
ambassador to Y ambassador to a country (Q29645886) class of ambassadors to a country (Q29918335) with Y = a country
ambassador of X to Y NONE ambassador of X

and

ambassador to Y

with X and Y = both a country
#display instance of class of ambassadors to/of a country 
#display instance of class of ambassadors to/of a country 
SELECT DISTINCT ?item ?itemLabel ?subclass ?subclassLabel
WHERE
{
    {?item wdt:P279 wd:Q29645880.} union {?item wdt:P279 wd:Q29645886}
    ?item wdt:P279 ?subclass.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" }
}
Try it!
#display instance of ambassadors to/of a country 
#display instance of ambassadors to/of a country 
SELECT DISTINCT ?item2 ?item2Label
WHERE
{
    {?item wdt:P279 wd:Q29645880.} union {?item wdt:P279 wd:Q29645886}
    ?item2 wdt:P31 ?item.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "fr, en" }
}
Try it!
#display instance of ambassadors with countries 
#display instance of ambassadors with countries 
SELECT DISTINCT ?item2 ?item2Label ?p1Label ?p2Label
WHERE
{
    ?item wdt:P279 wd:Q29645880.
    ?item_b wdt:P279 wd:Q29645886.
    ?item2 wdt:P31 ?item.
    ?item2 wdt:P31 ?item_b.
    ?item wdt:P17 ?p1.
    ?item_b wdt:P17 ?p2.
    filter (?p1 != ?p2)
    
    SERVICE wikibase:label { bd:serviceParam wikibase:language "fr, en" }
}
Try it!


Maintenance

[edit]
#potentials category without subject but maybe should be some ambassador position 
#potentials category without subject but maybe should be some ambassador position
SELECT DISTINCT ?item  ?itemLabel WHERE {
  ?item wdt:P31 wd:Q4167836.
  ?item rdfs:label ?itemLabel .
  FILTER(LANG(?itemLabel) = "en").
  FILTER(STRSTARTS(?itemLabel, "Category:Ambassadors")).
  FILTER NOT EXISTS{?item wdt:P301 ?_}
}
LIMIT 20 # too long and fail otherwise
Try it!
#duplicated instances of ambassadors to/of a country 
#duplicated instances of ambassadors to/of a country 
SELECT DISTINCT ?item ?itemLabel ?item1 ?item1Label ?item2 ?item2Label
WHERE
{
    {?item1 wdt:P279 wd:Q29645880.?item2 wdt:P279 wd:Q29645886}.
    FILTER (?item1 != ?item2).
  ?item wdt:P31 ?item1.
  ?item wdt:P31 ?item2.
  ?item_bis wdt:P31 ?item1.
  ?item_bis wdt:P31 ?item2.
  FILTER (?item != ?item_bis).
    SERVICE wikibase:label { bd:serviceParam wikibase:language "fr, en" }
}
Try it!
#item with (ambassador of x) or (ambassador of y) as P279 (probably instead of P31) 
#item with (ambassador of x) or (ambassador of y) as P279
#(probably instead of P31)
SELECT distinct ?item ?itemLabel ?class ?classLabel where{
  {?class wdt:wdt:P31 wd:Q29918328 .} union {?class wdt:P31 wd:Q29918335}
  ?item wdt:P279 ?class.
SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en" }
FILTER  NOT EXISTS { # know exceptions
    {?item wdt:P279 wd:Q30064715 }
    union
    {?item wdt:P279 wd:Q110620461 }
  }
}
Try it!
#display instance of ambassadors (to XOR of) a country 
#display instance of ambassadors (to XOR of) a country 
SELECT DISTINCT ?item ?itemLabel ?classLabel ?metaclassLabel
WHERE
{
      {?item wdt:P31/wdt:P279* wd:Q29645880 .} union {?item wdt:P31/wdt:P279* wd:Q29645886}
     OPTIONAL {?item wdt:P31 ?class.}
     OPTIONAL {?class wdt:P31 ?metaclass.}
  FILTER NOT EXISTS {?item wdt:P31/wdt:P279* wd:Q29645880 .?item wdt:P31/wdt:P279* wd:Q29645886}.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en" }
}
Try it!
#categories missing for instance of class of ambassadors to/of a country 
#categories missing for instance of class of ambassadors to/of a country 
SELECT DISTINCT ?item ?itemLabel ?subclass ?subclassLabel ?cat ?catLabel
WHERE
{
    {?item wdt:P279 wd:Q29645880.} union {?item wdt:P279 wd:Q29645886}
    ?item wdt:P279 ?subclass.
    FILTER NOT EXISTS {?item wdt:P910 ?cat}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" }
}
Try it!
#category with label starting with 'Category:Ambassadors' and with subject instance of list 
#category with label starting with 'Category:Ambassadors' and with subject instance of list
SELECT DISTINCT ?item  ?itemLabel WHERE {
  ?item wdt:P31 wd:Q4167836.
  ?item rdfs:label ?itemLabel1 .
  ?item wdt:P301 ?sub.
  ?sub wdt:P31 wd:Q13406463.
  FILTER(STRSTARTS(?itemLabel1, "Category:Ambassadors")).
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }

}
Try it!
#both ambassador and list instance (should be split) 
#both ambassador and list instance (should be split)
SELECT DISTINCT ?item  ?itemLabel WHERE {
  ?item wdt:P31/wdt:P279* wd:Q121998.
  ?item wdt:P31 wd:Q13406463.
  ?item rdfs:label ?itemLabel1.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Try it!

Automatic

[edit]
#categories incomplete for instance of class of ambassadors to a country 
#categories incomplete for instance of class of ambassadors to a country 
SELECT DISTINCT ?item ?itemLabel ?cat ?catLabel
WHERE
{   ?cat wdt:P31 wd:Q4167836.
    ?item wdt:P910 ?cat.
    ?item wdt:P31/wdt:P279* wd:Q29645886.
    FILTER NOT EXISTS {?cat wdt:P301 ?item_}.
    SERVICE wikibase:label { bd:serviceParam wikibase:language "fr,en" }
}
Try it!

and use my python script with the tool `add_subject_to_categories()`.

Ambassador to a country creation helper

[edit]
  1. complete a .csv with : country,category,enLabel,frLabel,enAlias,frAlias,modeCommand
  2. use my python script with `create_ambassadors_class(defaultmode=None)` (tip: you can set defaultmode to `to` or `of` and don’t fill modeCommand column).

→ Don't forget to run the automatic script for categories incomplete after.

Retrieved from "https://www.wikidata.org/w/index.php?title=User:Metamorforme42/Ambassadors&oldid=1659676645"