Florentyna

Links

• Wikidata:Database reports/Constraint violations/P2729
• Google Knowledge Graph
• quick_statements.php
• https://tools.wmflabs.org/quickstatements/#/batch
• phabricator.wikimedia.org/T147330
• User:Florentyna/common.js
• User:Florentyna/nameGuzzler.js
• User:Florentyna/namesZHsimple.js
• User:Florentyna/namesZHtrad.js
• WikiProject_Badminton
• Wikidata:Tools/Edit items - HarvestTemplates
• petscan

Badminton players without citizenship

SELECT ?item ?itemLabel WHERE {
   ?item wdt:P31 wd:Q5 .
   ?item wdt:P106 wd:Q13141064 .
   FILTER NOT EXISTS { ?item wdt:P27 ?dummy0 }
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }

Try it!

Badminton players from a specific country without birth date

SELECT ?item ?itemLabel WHERE {
   ?item wdt:P31 wd:Q5 .
   ?item wdt:P106 wd:Q13141064 .
   ?item wdt:P27 wd:Q668 .
   FILTER NOT EXISTS { ?item wdt:P569 ?dummy0 }
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }

Try it!

Badminton players without gender

SELECT ?item ?itemLabel WHERE {
   ?item wdt:P31 wd:Q5 .
   ?item wdt:P106 wd:Q13141064 .
   FILTER NOT EXISTS { ?item wdt:P21 ?dummy0 }
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }

Try it!

Chinese badminton players

SELECT ?item ?itemLabel WHERE {
 ?item wdt:P106 wd:Q13141064 .
 { ?item wdt:P27 wd:Q148. }
 UNION
 { ?item wdt:P27 wd:Q865. }
 UNION
 { ?item wdt:P27 wd:Q14773. }
 UNION
 { ?item wdt:P27 wd:Q8646. }
 SERVICE wikibase:label {
 bd:serviceParam wikibase:language "zh" .
 }
 }

Try it!

Missing gender by tournament type

SELECT ?item ?itemLabel ?participantLabel WHERE {
  {
    SELECT ?item ?itemLabel ?participantLabel (CONTAINS(?participantLabel, "Women's") AS ?is_woman) WHERE {
      ?item wdt:P31 wd:Q5; wdt:P106 wd:Q13141064; wdt:P1344 ?participant .
      MINUS { ?item wdt:P21 [] } .
      SERVICE wikibase:label {
        bd:serviceParam wikibase:language "en" .
      } .
    }
  } .
  FILTER( ?is_woman = true ) .
  #FILTER( ?is_woman = false ) . 
  #false is not the correct solution, because Mixed doubles will listed there, too
}

Try it!

Missing labels

SELECT ?item ?itemLabel ?itemDescription ?emptyOtherLanguageLabel WHERE {
  ?item wdt:P106 wd:Q13141064 .
  OPTIONAL {
    ?item rdfs:label ?emptyOtherLanguageLabel .
  	FILTER( LANG(?emptyOtherLanguageLabel) = "fr" ) . 
  }
  FILTER(!BOUND(?emptyOtherLanguageLabel))
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
}

Try it!

Replace rdfs:label by schema:description for missing descriptions. Replace "fr" by another language code for another missing language.

Number of Chinese labels

SELECT ?item ?itemLabel ?numberOfDifferentChineseLabels WHERE {
  {
    SELECT ?item (COUNT(DISTINCT ?plainlabel) AS ?numberOfDifferentChineseLabels) WHERE {
      {
        SELECT ?item WHERE {
          ?item wdt:P106 wd:Q13141064 .
        }
      }
      OPTIONAL {
        ?item rdfs:label ?label .
        BIND(STR(?label) AS ?plainlabel) .
      }
      FILTER( SUBSTR(LANG(?label), 0, 2) = "zh" ) . 
      FILTER( BOUND(?label) ) .
    } GROUP BY ?item
  }
  FILTER(?numberOfDifferentChineseLabels > 0) .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
} ORDER BY DESC(?numberOfDifferentChineseLabels)

Try it!

Chinese labels per all Chinese languages incl. yue and wuu

SELECT ?item ?itemLabel ?plainlabel (GROUP_CONCAT(?lang; separator=", ") as ?langs) WHERE {
  {
    SELECT ?item WHERE {
      ?item wdt:P106 wd:Q13141064 .
    }
  }
  OPTIONAL {
    ?item rdfs:label ?label .
    BIND(STR(?label) AS ?plainlabel) .
    BIND(LANG(?label) AS ?lang) .
  }
  FILTER( REGEX(LANG(?label), '^(zh.*|yue|wuu)$') ) . 
  FILTER( BOUND(?label) ) .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
} GROUP BY ?item ?itemLabel ?plainlabel ORDER BY ASC(?item)

Try it!

Chinese labels per ZH-Chinese languages (without yue and wuu)

SELECT ?item ?itemLabel ?plainlabel (GROUP_CONCAT(?lang; separator=", ") as ?langs) WHERE {
  {
    SELECT ?item WHERE {
      ?item wdt:P106 wd:Q13141064 .
    }
  }
  OPTIONAL {
    ?item rdfs:label ?label .
    BIND(STR(?label) AS ?plainlabel) .
    BIND(LANG(?label) AS ?lang) .
  }
  FILTER( SUBSTR(LANG(?label), 0, 2) = "zh" ) . 
  FILTER( BOUND(?label) ) .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" }
} GROUP BY ?item ?itemLabel ?plainlabel ORDER BY ASC(?item)

Try it!

Comparison of zh-hans and zh-hant

SELECT ?item ?itemLabel ?plainlabel (GROUP_CONCAT(?lang; separator=", ") as ?langs) WHERE {
  {
    SELECT ?item WHERE {
      ?item wdt:P106 wd:Q13141064 .
    }
  }
  OPTIONAL {
    ?item rdfs:label ?label .
    BIND(STR(?label) AS ?plainlabel) .
    BIND(LANG(?label) AS ?lang) .
  }
  FILTER( LANG(?label) = "zh-hant" ) .
  FILTER( BOUND(?label) ) .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "zh-hans" }
} GROUP BY ?item ?itemLabel ?plainlabel ORDER BY ASC(?item)

Try it!

Sports-Reference without BWF-ID

SELECT ?item ?itemLabel WHERE {
   ?item wdt:P106 wd:Q13141064 .
   FILTER EXISTS { ?item wdt:P1447 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P2729 ?dummy0 }
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }

Try it!

Article in a specific Wiki with a property on Wikidata

SELECT ?item ?itemLabel WHERE {
   ?item wdt:P31 wd:Q5 .
   ?item wdt:P106 wd:Q13141064 .
		FILTER EXISTS { ?wen schema:about ?item . ?wen schema:inLanguage "de" }
		SERVICE wikibase:label {
		bd:serviceParam wikibase:language "de,en" .
	}
}
GROUP BY ?item ?itemLabel

Try it!

Participants of tournaments

SELECT ?item ?itemLabel ?participantLabel WHERE {
  {
    SELECT ?item ?itemLabel ?participantLabel (CONTAINS(?participantLabel, "Bangladesh Badminton") AS ?is_Bangla) WHERE {
      ?item wdt:P31 wd:Q5; wdt:P106 wd:Q13141064; wdt:P1344 ?participant .
      SERVICE wikibase:label {
        bd:serviceParam wikibase:language "en" .
      } .
    }
  } .
  FILTER( ?is_Bangla = true ) .
}

Try it!

Missing name in native language

SELECT ?item ?itemLabel ?countryLabel WHERE {
   ?item wdt:P106 wd:Q13141064; wdt:P27 ?country .
   FILTER EXISTS { ?item wdt:P27 ?dummy0 }
   FILTER EXISTS { ?item wdt:P106 wd:Q13141064 }
   FILTER NOT EXISTS { ?item wdt:P1559 ?dummy0 }
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }
ORDER BY ?countryLabel

Try it!

No backlinks

SELECT DISTINCT ?item 
WHERE
{
  ?item wikibase:sitelinks 0 .
  ?item wdt:P31 wd:Q5 .
  ?item wdt:P21 ?dummy1 .
   ?item wdt:P106 wd:Q13141064 .
  OPTIONAL{
    ?backlink ?p1 ?item .
  }
  FILTER(!bound(?backlink))  
  OPTIONAL{
    ?item ?claim ?dummy0 .
    ?property wikibase:propertyType wikibase:ExternalId .
    ?property wikibase:directClaim ?claim
  }
  FILTER(!bound(?dummy0))
  OPTIONAL{
    ?item ?p2 [prov:wasDerivedFrom ?ref] .
    ?ref ?pr [] .
  }  
  FILTER(!bound(?ref))
}
Limit 100

Try it!

Article in zh not in de

SELECT DISTINCT ?item ?itemLabel WHERE {
   ?item wdt:P5008 wd:Q66098665 
  FILTER EXISTS { ?wzh schema:about ?item . ?wzh schema:inLanguage "zh" }
  FILTER NOT EXISTS { ?wde schema:about ?item . ?wde schema:inLanguage "de" }
		SERVICE wikibase:label {
		bd:serviceParam wikibase:language "de,zh" .
	}
}
GROUP BY ?item ?itemLabel

Try it!

Athletes without CGF-ID

SELECT ?item ?itemLabel ?participantLabel WHERE {
  {
    SELECT ?item ?itemLabel ?participantLabel (CONTAINS(?participantLabel, "Commonwealth") AS ?is_Bangla) WHERE {
      ?item wdt:P31 wd:Q5; wdt:P106 wd:Q13141064; wdt:P1344 ?participant .
      SERVICE wikibase:label {
        bd:serviceParam wikibase:language "en" .
      } .
    }
  } .
  FILTER( ?is_Bangla = true ) .
  FILTER NOT EXISTS { ?item wdt:P4548 ?dummy0 }
}

Try it!

Tournaments in 2017

SELECT ?item ?itemLabel WHERE {
  ?item wdt:P5008 wd:Q66098665 .
  ?item wdt:P585 ?_publication_date .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
FILTER (?_publication_date = "2017-00-00T00:00:00Z"^^xsd:dateTime)
}

Try it!

Wrong gender

SELECT ?item ?itemLabel ?participantLabel WHERE {
  {
    SELECT ?item ?itemLabel ?participantLabel (CONTAINS(?participantLabel, "Women") AS ?is_Bangla) WHERE {
      ?item wdt:P31 wd:Q5; wdt:P106 wd:Q13141064; wdt:P21 wd:Q6581097; wdt:P1344 ?participant .
      SERVICE wikibase:label {
        bd:serviceParam wikibase:language "en" .
      } .
    }
  } .
  FILTER( ?is_Bangla = true ) .
}

Try it!

Participants of tournaments in the 1990s without BWF-ID

SELECT ?item ?itemLabel ?participantLabel WHERE {
  {
    SELECT ?item ?itemLabel ?participantLabel (CONTAINS(?participantLabel, "199") AS ?is_Bangla) WHERE {
      ?item wdt:P31 wd:Q5; wdt:P106 wd:Q13141064; wdt:P1344 ?participant .
      SERVICE wikibase:label {
        bd:serviceParam wikibase:language "en" .
      } .
    }
  } .
  FILTER( ?is_Bangla = true ) .
  FILTER NOT EXISTS { ?item wdt:P2729 ?dummy0 }
}

Try it!

Participants of Asian Games

SELECT ?item ?itemLabel WHERE {
   ?item wdt:P106 wd:Q13141064 .
   ?item wdt:P1344 wd:Q495611
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }

Try it!

Search for point in time

SELECT ?item ?itemLabel ?participantLabel WHERE {
  {
    SELECT ?item ?itemLabel ?participantLabel (CONTAINS(?participantLabel, "T00:00:00Z") AS ?is_Bangla) WHERE {
      ?item wdt:P5008 wd:Q66098665; wdt:P585 ?participant .
      SERVICE wikibase:label {
        bd:serviceParam wikibase:language "en" .
      } .
    }
  } .
  FILTER( ?is_Bangla = true ) .
  FILTER EXISTS { ?item wdt:P585 ?dummy0 }
        }

Try it!

Start and end time

SELECT ?item ?itemLabel ?_start ?_end ?_instanceLabel
WHERE {
   ?item wdt:P5008 wd:Q66098665 .
   FILTER EXISTS  { ?item wdt:P580 ?dummy0 }
   ?item wdt:P580 ?_start.
   ?item wdt:P582 ?_end.
   ?item wdt:P31 ?_instance.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Try it!

Korean badminton players without McCune-Reischauer romanization

SELECT ?item ?itemLabel WHERE {
   ?item wdt:P31 wd:Q5 .
   ?item wdt:P106 wd:Q13141064 .
   ?item wdt:P27 wd:Q884 .
   FILTER NOT EXISTS { ?item wdt:P1942 ?dummy0 }
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }

Try it!

Badminton players without IDs, participations, awards, works

SELECT ?item ?itemLabel WHERE {
   ?item wdt:P31 wd:Q5 .
   ?item wdt:P106 wd:Q13141064 .
   FILTER NOT EXISTS { ?item wdt:P1344 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P2729 ?dummy0 }  
   FILTER NOT EXISTS { ?item wdt:P4548 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P2868 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P166 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P800 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P2581 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P213 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P214 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P3620 ?dummy0 }
   FILTER NOT EXISTS {?article schema:about ?item } 
   FILTER NOT EXISTS { ?item wdt:P4042 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P1741 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P646 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P4588 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P3973 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P166 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P3171 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P1447 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P3417 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P244 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P3222 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P4392 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P2671 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P1280 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P3670 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P4787 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P2029 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P4638 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P3988 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P8350 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P4613 ?dummy0 }
   SERVICE wikibase:label {
   bd:serviceParam wikibase:language "en" .
   }
 }

Try it!

Badminton people without a specific language label

SELECT ?item ?itemLabel ?itemDescription WHERE {
   ?item wdt:P31 wd:Q5 .
   ?item wdt:P641 wd:Q7291 .

 SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
 FILTER(NOT EXISTS {
   ?item rdfs:label ?lang_label.
   FILTER(LANG(?lang_label) = "eml") #with missing eml label
 })
}
ORDER BY ?itemLabel

Try it!

Locations of events with parts

SELECT ?item ?itemLabel ?location ?haspart WHERE {
   ?item wdt:P5008 wd:Q66098665; wdt:P276 ?location; wdt:P527 ?haspart.
   FILTER EXISTS { ?item wdt:P527 ?dummy0 }
   FILTER EXISTS { ?item wdt:P276 ?dummy0 }
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }

Try it!

Norwegian badminton players

SELECT ?item ?itemLabel WHERE {
   ?item wdt:P31 wd:Q5 .
   ?item wdt:P106 wd:Q13141064 .
   ?item wdt:P27 wd:Q20 . 
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }
ORDER BY ?itemLabel

Try it!

Location of main tournament page to parts of tournament

SELECT ?item ?itemLabel ?participant ?participantLabel ?location WHERE {
   ?item wdt:P17 wd:Q35; wdt:P5008 wd:Q66098665; wdt:P527 ?participant; wdt:P276 ?location .
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }

Try it!

Japanese name without kana

SELECT ?item ?itemLabel WHERE {
   ?item wdt:P27 wd:Q17 .
   ?item wdt:P106 wd:Q13141064 .
   FILTER EXISTS { ?item wdt:P1559 ?dummy0 }
   FILTER NOT EXISTS { ?item wdt:P1814 ?dummy0 }
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }

Try it!

Japanese translations

SELECT ?item ?itemLabel ?participantLabel WHERE {
   ?item wdt:P27 wd:Q17; wdt:P106 wd:Q13141064; wdt:P1559 ?participant .
   FILTER EXISTS { ?item wdt:P1559 ?dummy0 }
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }

Try it!

Category check for correct location

SELECT ?cat ?catLabel ?location ?locationLabel {
  ?cat p:P4224[ps:P4224 wd:Q13357858; pq:P276 ?location]
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
}

Try it!

Category of locations to location for tournaments

PREFIX mw: <http://tools.wmflabs.org/mw2sparql/ontology#>
SELECT DISTINCT ?tournament ?tournamentLabel ?location ?locationLabel {
  hint:Query hint:optimizer "None" .
  ?cat p:P4224[ps:P4224 wd:Q13357858; pq:P276 ?location] .
  ?catArticle schema:about ?cat
  SERVICE <http://tools.wmflabs.org/mw2sparql/sparql> {
    ?page mw:inCategory ?catArticle
  }
  ?page schema:about ?tournament . ?tournament wdt:P5008 wd:Q66098665
  FILTER NOT EXISTS { ?tournament wdt:P276 [] } 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,de" }
}

Try it!

Locations for Part-of-tournaments

SELECT ?parts ?partsLabel ?location ?locationLabel {
  ?tournament wdt:P5008 wd:Q66098665; wdt:P276 ?location; wdt:P527 ?parts .
  ?parts wdt:P5008 wd:Q66098665
  FILTER NOT EXISTS { ?parts wdt:P276 [] }
  FILTER NOT EXISTS { ?parts wdt:P2094 wd:Q63874701 }
  FILTER NOT EXISTS { ?parts wdt:P3085 [] }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,de" }
}

Try it!

Missing locations for for a specific country

SELECT ?item ?itemLabel WHERE {
  ?item wdt:P5008 wd:Q66098665 .
  ?item wdt:P17 wd:Q145 .
  FILTER NOT EXISTS { ?item wdt:P31 wd:Q18608583 }
  FILTER NOT EXISTS { ?item wdt:P276 ?dummy0 }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Try it!

Missing description in en

SELECT ?item ?itemLabel ?genderLabel ?itemDescription WHERE {
  ?item wdt:P5008 wd:Q66098665.  # focus badminton tournament
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,de,it,es,pt,no". }
  FILTER(NOT EXISTS {
    ?item schema:description ?itemdesc.
    FILTER(LANG(?itemdesc) = "en") # with missing language description
  })
}
order by ?itemLabel

Try it!

From participant to birth date

SELECT ?item ?itemLabel ?haspart ?haspartLabel WHERE {
   ?item wdt:P31 wd:Q5; wdt:P106 wd:Q13141064; wdt:P1344 ?haspart.
   FILTER NOT EXISTS { ?item wdt:P569 ?dummy0 }
   FILTER EXISTS { ?item wdt:P1344 ?dummy0 }
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }

Try it!

Irish badminton players without an article in en-wiki

SELECT ?item ?itemLabel WHERE {
   ?item wdt:P106 wd:Q13141064 .
   FILTER EXISTS { ?item wdt:P1532 wd:Q27 }
   FILTER NOT EXISTS { ?wen schema:about ?item . ?wen schema:inLanguage "en"  }
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }

Try it!

Badminton players born in a specific year

SELECT DISTINCT ?item ?itemLabel WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
  {
    SELECT DISTINCT ?item WHERE {
      ?item p:P569 ?statement_0.
      ?statement_0 psv:P569 ?statementValue_0.
      ?statementValue_0 wikibase:timePrecision ?precision_0.
      hint:Prior hint:rangeSafe "true"^^xsd:boolean.
      FILTER(?precision_0 = 11 )
      ?statementValue_0 wikibase:timeValue ?P569_0.
      hint:Prior hint:rangeSafe "true"^^xsd:boolean.
      FILTER((" 1899-00-00T00:00:00Z"^^xsd:dateTime <= ?P569_0) && (?P569_0 < " 1900-00-00T00:00:00Z"^^xsd:dateTime))
      ?item p:P641 ?statement1.
      ?statement1 (ps:P641/(wdt:P279*)) wd:Q7291.
      ?item p:P31 ?statement2.
      ?statement2 (ps:P31/(wdt:P279*)) wd:Q5.
    }
 }
 }

Try it!

Badminton championships in a specific year with start and end

SELECT ?item ?itemLabel ?_start ?_end ?_instanceLabel
WHERE {
   ?item wdt:P5008 wd:Q66098665 .
   FILTER EXISTS  { ?item wdt:P580 ?dummy0 }
   ?item wdt:P580 ?_start.
   ?item wdt:P582 ?_end.
   ?item wdt:P31 ?_instance.
   ?item wdt:P585 ?_publication_date .
   FILTER NOT EXISTS { ?item wdt:P31 wd:Q57733494 }
   FILTER (?_publication_date = "2016-00-00T00:00:00Z"^^xsd:dateTime)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de". }
}

Try it!

Badminton championships in 2020 without an article in de

SELECT ?item ?itemLabel WHERE {
  ?item wdt:P5008 wd:Q66098665 .
  ?item wdt:P585 ?_publication_date .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
FILTER (?_publication_date = "2020-00-00T00:00:00Z"^^xsd:dateTime)
FILTER NOT EXISTS { ?item wdt:P31 wd:Q57733494 }
FILTER NOT EXISTS { ?wde schema:about ?item . ?wde schema:inLanguage "de" }
}

Try it!

Missing Babel for badminton items in all languages

SELECT ?item ?itemLabel WHERE {
  ?item wdt:P641 wd:Q7291 . hint:Prior hint:runFirst true .
  ?wen schema:about ?item .  
  ?wen schema:isPartOf ?partOf .
  ?partOf wikibase:wikiGroup "wikipedia" .
  FILTER NOT EXISTS { ?item wdt:P31/wdt:P279* wd:Q4167836 . hint:Prior hint:gearing "forward". }
  FILTER NOT EXISTS { ?item wdt:P31 wd:Q11266439 .}
  FILTER NOT EXISTS { ?item wdt:P2581 [] .}
  FILTER NOT EXISTS { ?item wdt:P31 wd:Q15184295 .}
  FILTER NOT EXISTS { ?item wdt:P31 wd:Q11753321 .}
  FILTER NOT EXISTS { ?item wdt:P31 wd:Q17633526 .}
  FILTER NOT EXISTS { ?item wdt:P31 wd:Q19887878 .}
  SERVICE wikibase:label { bd:serviceParam wikibase:language 'en' .}
}

Try it!

Clubs without location

SELECT ?item ?itemLabel ?genderLabel ?itemDescription WHERE {
   ?item wdt:P31 wd:Q847017 .
   ?item wdt:P641 wd:Q7291 .
   FILTER NOT EXISTS { ?item wdt:P131 ?dummy0 }
   SERVICE wikibase:label {
     bd:serviceParam wikibase:language "en" .
   }
 }

Try it!

Missing name in native language (1)

SELECT ?item ?nameInLang (lang(?nameInLang) as ?langCode){
  ?item wdt:P106 wd:Q13141064 .
  
  ?item wdt:P1559 ?nameInLang .
  
  minus {
    ?item rdfs:label ?nameInLang .
  }
  minus { ?item skos:altLabel ?nameInLang . # filter out those with the name present as an alias }

Try it!

}}

Missing name in native language (2)

SELECT ?item ?nameInLang (lang(?nameInLang) as ?langCode){
  ?item wdt:P106 wd:Q13141064 .
  ?item wdt:P1559 ?nameInLang  .
  minus {
    ?item rdfs:label ?nameInLang .
  }
  minus {
   ?item skos:altLabel ?nameInLang . # filter out those with the name present as an alias
  }
  
  filter (lang(?nameInLang) = ?labelCode).
  values ?labelCode{
  "aa" "aae" "ab" "abs" "ace" "acf" "acm" "ady" "ady-cyrl" "aeb" "aeb-arab" "aeb-latn" "af" "agq" "ak" "aln" "als" "alt" "am" "ami" "an" "ang" "ann" "anp" "apc" "ar" "arc" "arn" "arq" "ary" "arz" "as" "ase" "ast" "atj" "av" "avk" "awa" "ay" "az" "azb" "ba" "bag" "ban" "ban-bali" "bar" "bas" "bat-smg" "bax" "bbc" "bbc-latn" "bbj" "bcc" "bci" "bcl" "bdr" "be" "be-tarask" "be-x-old" "bew" "bfd" "bg" "bgc" "bgn" "bh" "bho" "bi" "bjn" "bkc" "bkh" "bkm" "blk" "bm" "bn" "bo" "bpy" "bqi" "bqz" "br" "brh" "bs" "btm" "bto" "bug" "bxr" "byv" "ca" "cak" "cal" "cbk-zam" "ccp" "cdo" "cdo-hant" "cdo-latn" "ce" "ceb" "ch" "chn" "cho" "chr" "chy" "ckb" "cnh" "co" "cps" "cpx" "cpx-hans" "cpx-hant" "cpx-latn" "cr" "crh" "crh-cyrl" "crh-latn" "crh-ro" "cs" "csb" "cu" "cv" "cy" "da" "dag" "de" "de-at" "de-ch" "de-formal" "dga" "din" "diq" "dsb" "dtp" "dty" "dua" "dv" "dz" "ee" "efi" "egl" "el" "eml" "en" "en-ca" "en-gb" "en-us" "eo" "es" "es-419" "es-formal" "et" "eto" "etu" "eu" "ewo" "ext" "fa" "fat" "ff" "fi" "fit" "fiu-vro" "fj" "fkv" "fmp" "fo" "fon" "fr" "frc" "frp" "frr" "fur" "fy" "ga" "gaa" "gag" "gan" "gan-hans" "gan-hant" "gcf" "gcr" "gd" "gl" "gld" "glk" "gn" "gom" "gom-deva" "gom-latn" "gor" "got" "gpe" "grc" "gsw" "gu" "guc" "gur" "guw" "gv" "gya" "ha" "hak" "hak-hans" "hak-hant" "hak-latn" "haw" "he" "hi" "hif" "hif-latn" "hil" "hke" "hno" "ho" "hr" "hrx" "hsb" "hsn" "ht" "hu" "hu-formal" "hy" "hyw" "hz" "ia" "iba" "ibb" "id" "ie" "ig" "igl" "ii" "ik" "ike-cans" "ike-latn" "ilo" "inh" "io" "is" "isu" "isv-cyrl" "isv-latn" "it" "iu" "ja" "jam" "jbo" "jut" "jv" "ka" "kaa" "kab" "kai" "kbd" "kbd-cyrl" "kbp" "kcg" "kea" "ker" "kg" "kge" "khw" "ki" "kiu" "kj" "kjh" "kjp" "kk" "kk-arab" "kk-cn" "kk-cyrl" "kk-kz" "kk-latn" "kk-tr" "kl" "km" "kn" "knc" "ko" "ko-kp" "koi" "kr" "krc" "kri" "krj" "krl" "ks" "ks-arab" "ks-deva" "ksf" "ksh" "ksw" "ku" "ku-arab" "ku-latn" "kum" "kus" "kv" "kw" "ky" "la" "lad" "lb" "lbe" "lem" "lez" "lfn" "lg" "li" "lij" "liv" "lki" "lld" "lmo" "ln" "lns" "lo" "loz" "lrc" "lt" "ltg" "lua" "lus" "luz" "lv" "lzh" "lzz" "mad" "mag" "mai" "map-bms" "mcn" "mcp" "mdf" "mg" "mh" "mhr" "mi" "min" "mk" "ml" "mn" "mnc" "mnc-latn" "mnc-mong" "mni" "mnw" "mo" "mos" "mr" "mrh" "mrj" "ms" "ms-arab" "mt" "mua" "mui" "mus" "mwl" "my" "myv" "mzn" "na" "nah" "nan" "nan-hani" "nan-hant" "nan-latn-pehoeji" "nan-latn-tailo" "nap" "nb" "nds" "nds-nl" "ne" "new" "ng" "nge" "nia" "nit" "niu" "nl" "nl-informal" "nla" "nmg" "nmz" "nn" "nnh" "nnz" "no" "nod" "nog" "nov" "nqo" "nr" "nrm" "nso" "nup" "nv" "ny" "nyn" "nyo" "nys" "oc" "ojb" "olo" "om" "or" "os" "osa-latn" "ota" "pa" "pag" "pam" "pap" "pap-aw" "pcd" "pcm" "pdc" "pdt" "pfl" "pi" "pih" "pl" "pms" "pnb" "pnt" "prg" "ps" "pt" "pt-br" "pwn" "qu" "quc" "qug" "rgn" "rif" "rki" "rm" "rmc" "rmf" "rmy" "rn" "ro" "roa-rup" "roa-tara" "rsk" "ru" "rue" "rup" "ruq" "ruq-cyrl" "ruq-latn" "rut" "rw" "rwr" "ryu" "sa" "sah" "sat" "sc" "scn" "sco" "sd" "sdc" "sdh" "se" "se-fi" "se-no" "se-se" "sei" "ses" "sg" "sgs" "sh" "sh-cyrl" "sh-latn" "shi" "shi-latn" "shi-tfng" "shn" "shy" "shy-latn" "si" "simple" "sjd" "sje" "sju" "sk" "skr" "skr-arab" "sl" "sli" "sm" "sma" "smj" "smn" "sms" "sn" "so" "sq" "sr" "sr-ec" "sr-el" "srn" "sro" "srq" "ss" "st" "stq" "sty" "su" "sv" "sw" "syl" "szl" "szy" "ta" "tay" "tcy" "tdd" "te" "tet" "tg" "tg-cyrl" "tg-latn" "th" "ti" "tig" "tk" "tl" "tly" "tly-cyrl" "tn" "to" "tok" "tpi" "tpv" "tr" "tru" "trv" "ts" "tt" "tt-cyrl" "tt-latn" "ttj" "tum" "tvu" "tw" "ty" "tyv" "tzm" "udm" "ug" "ug-arab" "ug-latn" "uk" "ur" "uz" "uz-cyrl" "uz-latn" "ve" "vec" "vep" "vi" "vls" "vmf" "vmw" "vo" "vot" "vro" "vut" "wa" "wal" "war" "wes" "wls" "wo" "wuu" "wuu-hans" "wuu-hant" "wya" "xal" "xh" "xmf" "xsy" "yas" "yat" "yav" "ybb" "yi" "yo" "yrl" "yue" "yue-hans" "yue-hant" "za" "zea" "zgh" "zgh-latn" "zh" "zh-classical" "zh-cn" "zh-hans" "zh-hant" "zh-hk" "zh-min-nan" "zh-mo" "zh-my" "zh-sg" "zh-tw" "zh-yue" "zu" "mul"
}

 hint:Prior hint:runLast true # run this at last, the query optimizer gets confused and it is slow
}
  
}

Try it!

Mandantory language option for name in native language

Q4115189<TAB>P1559<TAB>en:"Name" should work (adding the English monolingual text "Name" to P1559 of Q4115189 in this case).