; Script generated by the Inno Setup Script Wizard.

; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!

#define MyAppName "Quoniam (64-bit)"

#define MyAppVersion "1.1.0"

#define MyAppPublisher "University of Girona"

#define MyAppURL "http://ima.udg.edu/~xavierb/quoniam"

#define MyAppExeName "Quoniam.exe"

[Setup]

AppId={{9A10DF1F-D4CF-4BBA-94B8-6C71373B8C4E}

AppName={#MyAppName}

AppVersion={#MyAppVersion}

;AppVerName={#MyAppName} {#MyAppVersion}

AppPublisher={#MyAppPublisher}

AppPublisherURL={#MyAppURL}

AppSupportURL={#MyAppURL}

AppUpdatesURL={#MyAppURL}

DefaultDirName={pf}\{#MyAppName}

DefaultGroupName={#MyAppName}

AllowNoIcons=yes

OutputDir=.\

OutputBaseFilename=Quoniam-v.{#MyAppVersion}-x64

SetupIconFile=..\icon.ico

Compression=lzma2

SolidCompression=yes

ArchitecturesAllowed=x64

ArchitecturesInstallIn64BitMode=x64

[Languages]

Name: "english"; MessagesFile: "compiler:Default.isl"

Name: "catalan"; MessagesFile: "compiler:Languages\Catalan.isl"

Name: "spanish"; MessagesFile: "compiler:Languages\Spanish.isl"

[Tasks]

Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked

[Files]

Source: "..\bazel-bin\src\quoniam.exe"; DestDir: "{app}"; Flags: ignoreversion

Source: "..\bazel-bin\src\assimp.dll"; DestDir: "{app}"; Flags: ignoreversion

Source: "..\bazel-bin\src\glew32.dll"; DestDir: "{app}"; Flags: ignoreversion

Source: "..\bazel-bin\src\opencv_core331.dll"; DestDir: "{app}"; Flags: ignoreversion

Source: "..\bazel-bin\src\opencv_highgui331.dll"; DestDir: "{app}"; Flags: ignoreversion

Source: "..\bazel-bin\src\opencv_imgproc331.dll"; DestDir: "{app}"; Flags: ignoreversion

Source: "..\bazel-bin\src\Qt5Core.dll"; DestDir: "{app}"; Flags: ignoreversion

Source: "..\bazel-bin\src\Qt5Gui.dll"; DestDir: "{app}"; Flags: ignoreversion

Source: "..\bazel-bin\src\Qt5OpenGL.dll"; DestDir: "{app}"; Flags: ignoreversion

Source: "..\bazel-bin\src\Qt5Widgets.dll"; DestDir: "{app}"; Flags: ignoreversion

Source: "C:\Qt\5.15.2\msvc2019_64\plugins\platforms\*"; DestDir: "{app}\platforms"; Flags: ignoreversion recursesubdirs createallsubdirs

Source: "C:\Qt\5.15.2\msvc2019_64\plugins\imageformats\*"; DestDir: "{app}\imageformats"; Flags: ignoreversion recursesubdirs createallsubdirs

Source: "..\shaders\*"; DestDir: "{app}\shaders"; Flags: ignoreversion recursesubdirs createallsubdirs

Source: "..\icon.ico"; DestDir: "{app}"; Flags: ignoreversion

Source: ".\redist\vcredist_x64.exe"; DestDir: {tmp}; Flags: deleteafterinstall

[Icons]

Name: "{group}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"

Name: "{group}\{cm:UninstallProgram,{#MyAppName}}"; Filename: "{uninstallexe}"

Name: "{commondesktop}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"; Tasks: desktopicon

[Run]

Filename: "{tmp}\vcredist_x64.exe"; Check: VCRedistNeedsInstall

Filename: "{app}\{#MyAppExeName}"; Description: "{cm:LaunchProgram,{#StringChange(MyAppName, '&', '&&')}}"; Flags: nowait postinstall skipifsilent

[Code]

#IFDEF UNICODE

#DEFINE AW "W"

#ELSE

#DEFINE AW "A"

#ENDIF

type

INSTALLSTATE = Longint;

const

INSTALLSTATE_INVALIDARG = -2; // An invalid parameter was passed to the function.

INSTALLSTATE_UNKNOWN = -1; // The product is neither advertised or installed.

INSTALLSTATE_ADVERTISED = 1; // The product is advertised but not installed.

INSTALLSTATE_ABSENT = 2; // The product is installed for a different user.

INSTALLSTATE_DEFAULT = 5; // The product is installed for the current user.

VC_2010_REDIST_X86 = '{196BB40D-1578-3D01-B289-BEFC77A11A1E}';

VC_2010_REDIST_X64 = '{DA5E371C-6333-3D8A-93A4-6FD5B20BCC6E}';

VC_2010_REDIST_IA64 = '{C1A35166-4301-38E9-BA67-02823AD72A1B}';

VC_2010_SP1_REDIST_X86 = '{F0C3E5D1-1ADE-321E-8167-68EF0DE699A5}';

VC_2010_SP1_REDIST_X64 = '{1D8E6291-B0D5-35EC-8441-6616F567A0F7}';

VC_2010_SP1_REDIST_IA64 = '{88C73C1C-2DE5-3B01-AFB8-B46EF4AB41CD}';

function MsiQueryProductState(szProduct: string): INSTALLSTATE;

external 'MsiQueryProductState{#AW}@msi.dll stdcall';

function VCVersionInstalled(const ProductID: string): Boolean;

begin

Result := MsiQueryProductState(ProductID) = INSTALLSTATE_DEFAULT;

end;

function VCRedistNeedsInstall: Boolean;

begin

Result := not VCVersionInstalled(VC_2010_SP1_REDIST_X64);

end;