[noscere@meg ~]$ sudo howdy clear
    No models created yet, can't clear them if they don't exist
    [noscere@meg ~]$ sudo howdy list
    Face models have not been initialized yet, please run:

            sudo howdy -U noscere add

    [noscere@meg ~]$ sudo howdy test
    Illegal instruction
    [noscere@meg ~]$ sudo howdy disable 0
    The disable option has already been set to false

# Maintainer: Frank Tackitt <[email protected]>
# Maintainer: boltgolt <[email protected]>
# Co-Maintainer: Raymo111 <[email protected]>
# Contributor: Kelley McChesney <[email protected]>

pkgname=howdy
pkgver=2.6.1
pkgrel=2
pkgdesc="Windows Hello for Linux"
arch=('x86_64')
url="https://github.com/boltgolt/howdy"
license=('MIT')
depends=(
        'opencv'
        'hdf5'
        'pam-python'
        'python'
        'python-pillow'
        'python-dlib'
        'python-face_recognition'
        'python-face_recognition_models'
        'python-click'
        'python-numpy'
        'python-opencv'
)
makedepends=(
        'cmake'
        'pkgfile'
)
backup=('usr/lib/security/howdy/config.ini')
source=(
        "https://github.com/boltgolt/howdy/archive/v${pkgver}.tar.gz"
        "https://github.com/davisking/dlib-models/raw/master/dlib_face_recognition_resnet_model_v1.dat.bz2"
        "https://github.com/davisking/dlib-models/raw/master/mmod_human_face_detector.dat.bz2"
        "https://github.com/davisking/dlib-models/raw/master/shape_predictor_5_face_landmarks.dat.bz2"
)
sha256sums=('f3f48599f78fd82b049539fcfc34de25c9435cad732697bdda94e85352964794'
            'abb1f61041e434465855ce81c2bd546e830d28bcbed8d27ffbe5bb408b11553a'
            'db9e9e40f092c118d5eb3e643935b216838170793559515541c56a2b50d9fc84'
            '6e787bbebf5c9efdb793f6cd1f023230c4413306605f24f299f12869f95aa472')

package() {
        # Installing the proper license files and the rest of howdy
        cd "${pkgname}-${pkgver}"
        install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
        mkdir -p "${pkgdir}/usr/lib/security/howdy"
        cp -r src/* "${pkgdir}/usr/lib/security/howdy"
        cp "${srcdir}/dlib_face_recognition_resnet_model_v1.dat" "${pkgdir}/usr/lib/security/howdy/dlib-data/"
        cp "${srcdir}/mmod_human_face_detector.dat" "${pkgdir}/usr/lib/security/howdy/dlib-data/"
        cp "${srcdir}/shape_predictor_5_face_landmarks.dat" "${pkgdir}/usr/lib/security/howdy/dlib-data/"
        chmod 600 -R "${pkgdir}/usr/lib/security/howdy"
        mkdir -p "${pkgdir}/usr/bin"
        ln -s /lib/security/howdy/cli.py "${pkgdir}/usr/bin/howdy"
        chmod  x "${pkgdir}/usr/lib/security/howdy/cli.py"
        mkdir -p "${pkgdir}/usr/share/bash-completion/completions"
        cp autocomplete/howdy "${pkgdir}/usr/share/bash-completion/completions/howdy"
}